One way to change font sizes in your ODS output is by using the style that is used in the ODS <destination> statement. Two main parameters control the overall size of typical ODS PRINTER (PCL/PDF/PS) output: the font size and the table CELLPADDING. (The cell padding is the space on the top, bottom, right, and left of the cells, between the actual cell text and the rules.)

For example, the code below shrinks the output to about 80% of the usual size:

proc template;
   define style styles.smaller;
   parent = styles.printer;
      class fonts from fonts /  /* Reduce all sizes by 2pt */
            'TitleFont2' = ("Times",10pt,Bold Italic)
            'TitleFont' = ("Times",11pt,Bold Italic)
            'StrongFont' = ("Times",8pt,Bold)
            'EmphasisFont' = ("Times",8pt,Italic)
            'FixedEmphasisFont' = ("Courier New, Courier",7pt,Italic)
            'FixedStrongFont' = ("Courier New, Courier",7pt,Bold)
            'FixedHeadingFont' = ("Courier New, Courier",7pt,Bold)
            'BatchFixedFont' = ("SAS Monospace, Courier New, Courier",5pt)
            'FixedFont' = ("Courier New, Courier",7pt)
            'headingEmphasisFont' = ("Times",9pt,Bold Italic)
            'headingFont' = ("Times",9pt,Bold)
            'docFont' = ("Times",8pt);
      class Table from Output /
            rules = ALL
            cellpadding = 2pt     /* Reduced from 4pt to 2pt */
            cellspacing = 0.25pt
            borderwidth = 0.75pt;
   end;
run;

ods pdf file="my-file.pdf" style=styles.smaller;

proc print data=sashelp.class; 
run;

ods pdf close;

For an example of how to do this in the ODS RTF destination, see Usage Note 24489: How can I reduce or shrink the font sizes throughout my RTF document?.